mirror of
https://github.com/pret/pokecrystal.git
synced 2026-08-05 02:37:51 -05:00
a55bc33d67
Some checks are pending
CI / build (push) Waiting to run
- Use single-quoted character literals or `CHARVAL` when you need
a character's numeric value; using strings as numbers is deprecated
- Use `?` to silence a node in warning/error location backtraces
- Use `===` and `!==` instead of `STRCMP`, and `++` instead of `STRCAT`
- Use `__SCOPE__` instead of checking for `..` and `.` separately
- Use `#string` instead of `"{string}"`
- All programs (rgbasm, rgblink, rgbfix, rgbgfx) support `-W` warnings
- `rgbgfx --colors dmg` is short for `rgbgfx --colors dmg=e4`
93 lines
1.3 KiB
NASM
93 lines
1.3 KiB
NASM
PrintMonTypes:
|
|
; Print one or both types of [wCurSpecies]
|
|
; on the stats screen at hl.
|
|
|
|
push hl
|
|
call GetBaseData
|
|
pop hl
|
|
|
|
push hl
|
|
ld a, [wBaseType1]
|
|
call .Print
|
|
|
|
; Single-typed monsters really
|
|
; have two of the same type.
|
|
ld a, [wBaseType1]
|
|
ld b, a
|
|
ld a, [wBaseType2]
|
|
cp b
|
|
pop hl
|
|
jr z, .hide_type_2
|
|
|
|
ld bc, SCREEN_WIDTH
|
|
add hl, bc
|
|
|
|
.Print:
|
|
ld b, a
|
|
jr PrintType
|
|
|
|
.hide_type_2
|
|
; Erase any type name that was here before.
|
|
; Seems to be pointless in localized versions.
|
|
ld a, ' '
|
|
ld bc, SCREEN_WIDTH - 3
|
|
add hl, bc
|
|
ld [hl], a
|
|
inc bc
|
|
add hl, bc
|
|
ld bc, NAME_LENGTH_JAPANESE - 1
|
|
jp ByteFill
|
|
|
|
PrintMoveType:
|
|
; Print the type of move b at hl.
|
|
|
|
push hl
|
|
ld a, b
|
|
dec a
|
|
ld bc, MOVE_LENGTH
|
|
ld hl, Moves
|
|
call AddNTimes
|
|
ld de, wStringBuffer1
|
|
ld a, BANK(Moves)
|
|
call FarCopyBytes
|
|
ld a, [wStringBuffer1 + MOVE_TYPE]
|
|
pop hl
|
|
|
|
ld b, a
|
|
|
|
PrintType:
|
|
; Print type b at hl.
|
|
|
|
ld a, b
|
|
|
|
push hl
|
|
add a
|
|
ld hl, TypeNames
|
|
ld e, a
|
|
ld d, 0
|
|
add hl, de
|
|
ld a, [hli]
|
|
ld e, a
|
|
ld d, [hl]
|
|
pop hl
|
|
|
|
jp PlaceString
|
|
|
|
GetTypeName:
|
|
; Copy the name of type [wNamedObjectIndex] to wStringBuffer1.
|
|
|
|
ld a, [wNamedObjectIndex]
|
|
ld hl, TypeNames
|
|
ld e, a
|
|
ld d, 0
|
|
add hl, de
|
|
add hl, de
|
|
ld a, [hli]
|
|
ld h, [hl]
|
|
ld l, a
|
|
ld de, wStringBuffer1
|
|
ld bc, MOVE_NAME_LENGTH
|
|
jp CopyBytes
|
|
|
|
INCLUDE "data/types/names.asm"
|